Featured image of post MDN ブロックくずしゲームでウェブゲーム開発に入門してみた。その2

MDN ブロックくずしゲームでウェブゲーム開発に入門してみた。その2

「ボールを動かす」編

このプログラムはGitHub Pagesで公開しています。

MDN web docs にある 「そのままのJavaScriptを使ったブロックくずしゲーム」 の2番目のステップ。

lesson02

1
2
3
aki:~/breakout$ cp -r lesson01/ lesson02
aki:~/breakout$ cd lesson02/
aki:~/breakout/lesson02$

lesson01 をコピーした lesson02 を用意して続きを始める。

今回は ボールを動かす

描画ループを定義する

Halogenドキュメントのこれを参考にして書く。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
module Breakout (component) where

import Prelude
import CSS (margin, padding, px)
import Control.Monad.Rec.Class (forever)
import Data.Maybe (Maybe(..))
import Data.Time.Duration (Milliseconds(..))
import Effect (Effect)
import Effect.Aff as Aff
import Effect.Aff.Class (class MonadAff)
import Graphics.Canvas (CanvasElement)
import Graphics.Canvas as Canvas
import Halogen as H
import Halogen.HTML as HH
import Halogen.HTML.CSS (style)
import Halogen.HTML.Properties as HP
import Halogen.Subscription as HS
import Math as Math

canvasId :: String
canvasId = "myCanvas"

type State
  = { maybeCanvas :: Maybe CanvasElement
    }

data Action
  = Initialize
  | Tick

component :: forall query input output m. MonadAff m => H.Component query input output m
component =
  H.mkComponent
    { initialState
    , render
    , eval:
        H.mkEval
          $ H.defaultEval
              { handleAction = handleAction
              , initialize = Just Initialize
              }
    }

initialState :: forall i. i -> State
initialState _ = { maybeCanvas: Nothing }

render :: forall m. State -> H.ComponentHTML Action () m
render _ =
  HH.main
    [ style do
        margin (px 0.0) (px 0.0) (px 0.0) (px 0.0)
        padding (px 0.0) (px 0.0) (px 0.0) (px 0.0)
    ]
    [ HH.canvas
        [ HP.id canvasId
        , HP.width 480
        , HP.height 320
        ]
    ]

handleAction :: forall output m. MonadAff m => Action -> H.HalogenM State Action () output m Unit
handleAction = case _ of
  Initialize -> do
    maybeCanvas <- H.liftEffect $ Canvas.getCanvasElementById canvasId
    H.modify_ \st -> st { maybeCanvas = maybeCanvas }
    _ <- H.subscribe =<< timer Tick
    pure unit
  Tick -> do
    (state :: State) <- H.get
    H.liftEffect $ draw state.maybeCanvas

timer :: forall m a. MonadAff m => a -> m (HS.Emitter a)
timer val = do
  { emitter, listener } <- H.liftEffect HS.create
  _ <-
    H.liftAff $ Aff.forkAff
      $ forever do
          Aff.delay $ Milliseconds 10.0
          H.liftEffect $ HS.notify listener val
  pure emitter

draw :: Maybe CanvasElement -> Effect Unit
draw Nothing = mempty

draw (Just canvas) = do
  ctx <- Canvas.getContext2D canvas
  --
  Canvas.beginPath ctx
  Canvas.arc ctx
    $ { x: 50.0
      , y: 50.0
      , radius: 10.0
      , start: 0.0
      , end: Math.pi * 2.0
      }
  Canvas.setFillStyle ctx "#0095DD"
  Canvas.fill ctx
  Canvas.closePath ctx

ビルドしてWebブラウザで見る。

1
2
3
aki:~/breakout/lesson01$ spago bundle-app
[info] Build succeeded.
[info] Bundle succeeded and output file to index.js

lesson02-1

ボールを動かす

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
module Breakout (component) where

import Prelude
import CSS (margin, padding, px)
import Control.Monad.Rec.Class (forever)
import Data.Maybe (Maybe(..), maybe)
import Data.Time.Duration (Milliseconds(..))
import Effect (Effect)
import Effect.Aff as Aff
import Effect.Aff.Class (class MonadAff)
import Graphics.Canvas (CanvasElement, Dimensions)
import Graphics.Canvas as Canvas
import Halogen as H
import Halogen.HTML as HH
import Halogen.HTML.CSS (style)
import Halogen.HTML.Properties as HP
import Halogen.Subscription as HS
import Math as Math

canvasId :: String
canvasId = "myCanvas"

type Dataset
  = { x :: Number
    , y :: Number
    , dx :: Number
    , dy :: Number
    }

type State
  = Maybe
      { canvas :: CanvasElement
      , dataset :: Dataset
      }

data Action
  = Initialize
  | Tick

component :: forall query input output m. MonadAff m => H.Component query input output m
component =
  H.mkComponent
    { initialState
    , render
    , eval:
        H.mkEval
          $ H.defaultEval
              { handleAction = handleAction
              , initialize = Just Initialize
              }
    }

initialState :: forall i. i -> State
initialState _ = Nothing

render :: forall m. State -> H.ComponentHTML Action () m
render _ =
  HH.main
    [ style do
        margin (px 0.0) (px 0.0) (px 0.0) (px 0.0)
        padding (px 0.0) (px 0.0) (px 0.0) (px 0.0)
    ]
    [ HH.canvas
        [ HP.id canvasId
        , HP.width 480
        , HP.height 320
        ]
    ]

handleAction :: forall output m. MonadAff m => Action -> H.HalogenM State Action () output m Unit
handleAction = case _ of
  Initialize -> do
    maybeCanvas <- H.liftEffect $ Canvas.getCanvasElementById canvasId
    case maybeCanvas of
      Nothing -> H.put Nothing
      Just canvas -> do
        dim <- H.liftEffect $ Canvas.getCanvasDimensions canvas
        H.put $ initialize canvas dim
        _ <- H.subscribe =<< timer Tick
        pure unit
  Tick ->
    H.get
      >>= maybe mempty \state -> do
          let
            (newDataset :: Dataset) =
              state.dataset
                { x = state.dataset.x + state.dataset.dx
                , y = state.dataset.y + state.dataset.dy
                }
          H.liftEffect $ draw state.canvas state.dataset
          H.put $ Just state { dataset = newDataset }
  where
  initialize :: CanvasElement -> Dimensions -> State
  initialize canvas dim =
    Just
      { canvas: canvas
      , dataset:
          { x: dim.width / 2.0
          , y: dim.height - 30.0
          , dx: 2.0
          , dy: (-2.0)
          }
      }

draw :: CanvasElement -> Dataset -> Effect Unit
draw canvas ds = do
  ctx <- Canvas.getContext2D canvas
  --
  Canvas.beginPath ctx
  Canvas.arc ctx
    { x: ds.x
    , y: ds.y
    , radius: 10.0
    , start: 0.0
    , end: Math.pi * 2.0
    }
  Canvas.setFillStyle ctx "#0095DD"
  Canvas.fill ctx
  Canvas.closePath ctx

timer :: forall m a. MonadAff m => a -> m (HS.Emitter a)
timer val = do
  { emitter, listener } <- H.liftEffect HS.create
  _ <-
    H.liftAff $ Aff.forkAff
      $ forever do
          Aff.delay $ Milliseconds 10.0
          H.liftEffect $ HS.notify listener val
  pure emitter

結果こうなる。

lesson02-2

フレームの後にCanvasを消去する

draw関数をこう変更してビルドすると

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
draw :: CanvasElement -> Dataset -> Effect Unit
draw canvas ds = do
  ctx <- Canvas.getContext2D canvas
  dim <- Canvas.getCanvasDimensions canvas
  --
  Canvas.clearRect ctx { x: 0.0, y: 0.0, width: dim.width, height: dim.height }
  Canvas.beginPath ctx
  Canvas.arc ctx
    { x: ds.x
    , y: ds.y
    , radius: 10.0
    , start: 0.0
    , end: Math.pi * 2.0
    }
  Canvas.setFillStyle ctx "#0095DD"
  Canvas.fill ctx
  Canvas.closePath ctx

今度は軌跡のないボールがみえるはずです。

ですね。

コードを整える

こうなった

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
module Breakout (component) where

import Prelude
import CSS (background, block, display, margin, marginBottom, marginLeft, marginRight, marginTop, padding, px, rgb)
import CSS.Common (auto)
import Control.Monad.Rec.Class (forever)
import Data.Maybe (Maybe(..), maybe)
import Data.Time.Duration (Milliseconds(..))
import Effect (Effect)
import Effect.Aff as Aff
import Effect.Aff.Class (class MonadAff)
import Graphics.Canvas (CanvasElement, Dimensions)
import Graphics.Canvas as Canvas
import Halogen as H
import Halogen.HTML as HH
import Halogen.HTML.CSS (style)
import Halogen.HTML.Properties as HP
import Halogen.Subscription as HS
import Math as Math

canvasId :: String
canvasId = "myCanvas"

type Dataset
  = { x :: Number
    , y :: Number
    , dx :: Number
    , dy :: Number
    }

type State
  = Maybe
      { canvas :: CanvasElement
      , dataset :: Dataset
      }

data Action
  = Initialize
  | Tick

component :: forall query input output m. MonadAff m => H.Component query input output m
component =
  H.mkComponent
    { initialState
    , render
    , eval:
        H.mkEval
          $ H.defaultEval
              { handleAction = handleAction
              , initialize = Just Initialize
              }
    }

initialState :: forall i. i -> State
initialState _ = Nothing

render :: forall m. State -> H.ComponentHTML Action () m
render _ =
  HH.main
    [ style do
        margin (px 0.0) (px 0.0) (px 0.0) (px 0.0)
        padding (px 0.0) (px 0.0) (px 0.0) (px 0.0)
    ]
    [ HH.canvas
        [ style do
            background (rgb 238 238 238)
            display block
            marginTop (px 0.0)
            marginRight auto
            marginBottom (px 0.0)
            marginLeft auto
        , HP.id canvasId
        , HP.width 480
        , HP.height 320
        ]
    ]

handleAction :: forall output m. MonadAff m => Action -> H.HalogenM State Action () output m Unit
handleAction = case _ of
  Initialize -> do
    maybeCanvas <- H.liftEffect $ Canvas.getCanvasElementById canvasId
    case maybeCanvas of
      Nothing -> H.put Nothing
      Just canvas -> do
        dim <- H.liftEffect $ Canvas.getCanvasDimensions canvas
        H.put $ initialize canvas dim
        _ <- H.subscribe =<< timer Tick
        pure unit
  Tick ->
    H.get
      >>= maybe mempty \state -> do
          H.liftEffect $ draw state.canvas state.dataset
          H.put $ Just state { dataset = nextDataset state.dataset }
  where
  initialize :: CanvasElement -> Dimensions -> State
  initialize canvas dim =
    Just
      { canvas: canvas
      , dataset:
          { x: dim.width / 2.0
          , y: dim.height - 30.0
          , dx: 2.0
          , dy: (-2.0)
          }
      }

drawBall :: CanvasElement -> Dataset -> Effect Unit
drawBall canvas ds = do
  ctx <- Canvas.getContext2D canvas
  --
  Canvas.beginPath ctx
  Canvas.arc ctx
    { x: ds.x
    , y: ds.y
    , radius: 10.0
    , start: 0.0
    , end: Math.pi * 2.0
    }
  Canvas.setFillStyle ctx "#0095DD"
  Canvas.fill ctx
  Canvas.closePath ctx

draw :: CanvasElement -> Dataset -> Effect Unit
draw canvas ds = do
  ctx <- Canvas.getContext2D canvas
  dim <- Canvas.getCanvasDimensions canvas
  --
  Canvas.clearRect ctx { x: 0.0, y: 0.0, width: dim.width, height: dim.height }
  drawBall canvas ds

nextDataset :: Dataset -> Dataset
nextDataset dataset =
  dataset
    { x = dataset.x + dataset.dx
    , y = dataset.y + dataset.dy
    }

timer :: forall m a. MonadAff m => a -> m (HS.Emitter a)
timer val = do
  { emitter, listener } <- H.liftEffect HS.create
  _ <-
    H.liftAff $ Aff.forkAff
      $ forever do
          Aff.delay $ Milliseconds 10.0
          H.liftEffect $ HS.notify listener val
  pure emitter

GitHubリポジトリ

コードはGitHub上にあります。
https://github.com/ak1211/breakout

まだつづく

よてい

comments powered by Disqus

This website uses cookies to improve your experience.
このサイトは「Googleアナリティクス」を使用しています。
Googleアナリティクスはデータの収集のためにCookieを使用しています。


Built with Hugo
テーマ StackJimmy によって設計されています。